*     F08JCF Example Program Text
*     Mark 20 Revised. NAG Copyright 2001.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, LDZ
      PARAMETER        (NMAX=8,LDZ=NMAX)
      INTEGER          LWORK, LIWORK
      PARAMETER        (LWORK=NMAX*NMAX+4*NMAX+1,LIWORK=5*NMAX+3)
*     .. Local Scalars ..
      INTEGER          I, IFAIL, INFO, N
      CHARACTER        JOB
*     .. Local Arrays ..
      DOUBLE PRECISION D(NMAX), E(NMAX), WORK(LWORK), Z(LDZ,NMAX)
      INTEGER          IWORK(LIWORK)
*     .. External Subroutines ..
      EXTERNAL         DSTEVD, X04CAF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F08JCF Example Program Results'
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N
      IF (N.LE.NMAX) THEN
*
*        Read T from data file
*
         READ (NIN,*) (D(I),I=1,N)
         READ (NIN,*) (E(I),I=1,N-1)
*
         READ (NIN,*) JOB
*
*        Calculate all the eigenvalues and eigenvectors of T
*
         CALL DSTEVD(JOB,N,D,E,Z,LDZ,WORK,LWORK,IWORK,LIWORK,INFO)
*
         WRITE (NOUT,*)
         IF (INFO.GT.0) THEN
            WRITE (NOUT,*) 'Failure to converge.'
         ELSE
*
*           Print eigenvalues and eigenvectors
*
            WRITE (NOUT,*) 'Eigenvalues'
            WRITE (NOUT,99999) (D(I),I=1,N)
            WRITE (NOUT,*)
            IFAIL = 0
*
            CALL X04CAF('General',' ',N,N,Z,LDZ,'Eigenvectors',IFAIL)
*
         END IF
      END IF
      STOP
*
99999 FORMAT (3X,(8F8.4))
      END