*     F04CHF Example Program Text
*     Mark 21 Release. NAG Copyright 2004.
*     .. Parameters ..
      INTEGER          NIN, NOUT
      PARAMETER        (NIN=5,NOUT=6)
      INTEGER          NMAX, NRHSMX
      PARAMETER        (NMAX=8,NRHSMX=2)
      INTEGER          LDA, LDB
      PARAMETER        (LDA=NMAX,LDB=NMAX)
*     .. Local Scalars ..
      DOUBLE PRECISION ERRBND, RCOND
      INTEGER          I, IERR, IFAIL, J, N, NRHS
*     .. Local Arrays ..
      COMPLEX *16      A(LDA,NMAX), B(LDB,NRHSMX)
      INTEGER          IPIV(NMAX)
      CHARACTER        CLABS(1), RLABS(1)
*     .. External Subroutines ..
      EXTERNAL         F04CHF, X04DBF
*     .. Executable Statements ..
      WRITE (NOUT,*) 'F04CHF Example Program Results'
      WRITE (NOUT,*)
*     Skip heading in data file
      READ (NIN,*)
      READ (NIN,*) N, NRHS
      IF (N.LE.NMAX .AND. NRHS.LE.NRHSMX) THEN
*
*        Read the upper triangular part of A from data file
*
         READ (NIN,*) ((A(I,J),J=I,N),I=1,N)
*
*        Read B from data file
*
         READ (NIN,*) ((B(I,J),J=1,NRHS),I=1,N)
*
*        Solve the equations AX = B for X
*
         IFAIL = -1
         CALL F04CHF('Upper',N,NRHS,A,LDA,IPIV,B,LDB,RCOND,ERRBND,IFAIL)
*
         IF (IFAIL.EQ.0) THEN
*
*           Print solution, estimate of condition number and approximate
*           error bound
*
            IERR = 0
            CALL X04DBF('General',' ',N,NRHS,B,LDB,'Bracketed',' ',
     +                  'Solution','Integer',RLABS,'Integer',CLABS,80,0,
     +                  IERR)
*
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Estimate of condition number'
            WRITE (NOUT,99999) 1.0D0/RCOND
            WRITE (NOUT,*)
            WRITE (NOUT,*)
     +        'Estimate of error bound for computed solutions'
            WRITE (NOUT,99999) ERRBND
         ELSE IF (IFAIL.EQ.N+1) THEN
*
*           Matrix A is numerically singular.  Print estimate of
*           reciprocal of condition number and solution
*
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Estimate of reciprocal of condition number'
            WRITE (NOUT,99999) RCOND
*
            WRITE (NOUT,*)
            IERR = 0
            CALL X04DBF('General',' ',N,NRHS,B,LDB,'Bracketed',' ',
     +                  'Solution','Integer',RLABS,'Integer',CLABS,80,0,
     +                  IERR)
*
         ELSE IF (IFAIL.GT.0 .AND. IFAIL.LE.N) THEN
*
*           The upper triangular matrix U is exactly singular.  Print
*           details of factorization
*
            WRITE (NOUT,*)
            IERR = 0
            CALL X04DBF('Upper','Non-unit diagonal',N,N,A,LDA,
     +                  'Bracketed',' ','Details of factorization',
     +                  'Integer',RLABS,'Integer',CLABS,80,0,IERR)
*
*           Print pivot indices
*
            WRITE (NOUT,*)
            WRITE (NOUT,*) 'Pivot indices'
            WRITE (NOUT,99998) (IPIV(I),I=1,N)
         END IF
      ELSE
         WRITE (NOUT,*) 'NMAX and/or NRHSMX too small'
      END IF
      STOP
*
99999 FORMAT (8X,1P,E9.1)
99998 FORMAT ((1X,7I11))
      END